MQL4プログラミング　第14回　バイナリーの自動エントリー（２）

// prg-0014.mq4
#property copyright "Copyright 2024, smile-invest-blog.com"
#property link      "https://www.smile-invest-blog.com/prg-0014/"
#property strict
#property indicator_chart_window
#property indicator_buffers 2
#property indicator_color1 Yellow
#property indicator_color2 Red
#property indicator_width1 2
#property indicator_width2 2

#define PREFIX_VLINE "VLine_"

double Log1Up[];   // Highサイン用バッファ
double Log1Down[]; // Low　サイン用バッファ
int    realBars = 0;

int shortMaPeriod = 10;  // 短期移動平均線の期間
int longMaPeriod  = 30;  // 長期移動平均線の期間

//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- indicator buffers mapping
   SetIndexStyle(0, DRAW_ARROW, EMPTY);
   SetIndexArrow(0, 233);
   SetIndexBuffer(0, Log1Up);
   SetIndexStyle(1, DRAW_ARROW, EMPTY);
   SetIndexArrow(1, 234);
   SetIndexBuffer(1, Log1Down);
   
//---
   return(INIT_SUCCEEDED);
  }

//+------------------------------------------------------------------+
//| start function
//+------------------------------------------------------------------+
int start() {
   bool ret_hantei;  // hantei関数の結果格納用
   int counted_bars=IndicatorCounted(); 
   int limit = Bars - counted_bars;

   for(int i = limit - 1; i >= 0; i--) {
      if(i == 0) {
         Log1Down[i] = EMPTY_VALUE;
         Log1Up[i]   = EMPTY_VALUE;

         ret_hantei = hantei(i);    // 上下サイン表示の判定を関数化した
         if (ret_hantei == true) {  // hantei関数の結果がtrueの時
            if (realBars < Bars) {  // １本のローソク足で１回だけ実行するための条件
               realBars = Bars;     // realBarsをBarsにする事で同じローソク足では１回だけ実行する
               if (Log1Up[i] != EMPTY_VALUE) {           // hantei関数内で上サイン表示と判定された
                  Alert(Symbol(), " *** High ***");
               }
               else if (Log1Down[i] != EMPTY_VALUE) {    // hantei関数内で下サイン表示と判定された
                  Alert(Symbol(), " *** Low ***");
               }
            }
         }

         if (TaskPeriod()){
            if (Log1Up[i+1] != EMPTY_VALUE) {
               entry(1, true);
            }
            if (Log1Down[i+1] != EMPTY_VALUE) {
               entry(0, true);
            }
         }
      }
   }

   return(0);
}

//+------------------------------------------------------------------+
//| エントリーの条件判定関数
//| int i メイン関数からのiの値
//+------------------------------------------------------------------+
bool hantei(int i) {
   double UpSign, DnSign;

   UpSign = getSign(0, i);
   DnSign = getSign(1, i);

   if (UpSign != EMPTY_VALUE) {
      // Highサイン
      Log1Up[i] = Low[i] - 10 * Point;
      return true;
   }
   else if (DnSign != EMPTY_VALUE) {
      // Lowサイン
      Log1Down[i] = High[i] + 10 * Point;
      return true;
   }

   return false;

}

//+------------------------------------------------------------------+
//| getSign メイン
//| 引数1 バッファの番号、
//| 引数2 シフト数、
//+------------------------------------------------------------------+
double getSign(int cNo, int shift) {
   double ret;

   ret = iCustom(                  // カスタムインジケータ呼び出し
                   NULL,           // 通貨ペア
                   0,              // 時間軸
                   "L-blog_0006",  // ｶｽﾀﾑｲﾝｼﾞｹｰﾀ名
                   cNo,            // ｶｽﾀﾑｲﾝｼﾞｹｰﾀのインジケータバッファインデックス
                   shift           // バーシフト
                );
   return ret;
}

//+------------------------------------------------------------------+
//| entry function                         |
//| 引数1 1:Highエントリー、0:Lowエントリー、
//| 引数2 false:手動エントリー、true:自動エントリー、
//+------------------------------------------------------------------+
void entry(int high_low, bool isAuto) {
   string strEntryCmd = " AMT";

/*
   アラートコマンドリスト（AMT側で設定すること）
   AMT1MA
   AMT1MM
   AMT5MA
   AMT5MM
   AMT15MA
   AMT15MM
   AMT60MA
   AMT60MM
   (AMTの個別アラート設定でそれぞれにHigh, Low の文字列を設定する）
*/
   if (Period() == 1) {
      strEntryCmd += "1M";
   }
   if (Period() == 5) {
      strEntryCmd += "5M";
   }
   if (Period() == 15) {
      strEntryCmd += "15M";
   }
   if (Period() == 60) {
      strEntryCmd += "1H";
   }

   if (isAuto) {
      strEntryCmd += "A";
   }
   else {
      strEntryCmd += "M";
   }

   if (high_low == 1) {
      strEntryCmd += " ***HIGH***";
   }
   else {
      strEntryCmd += " ***LOW***";
   }
   
   Alert(Symbol(), strEntryCmd);

   if (high_low == 1) {
      drawVLine(Lime);
   }
   if (high_low == 0) {
      drawVLine(Red);
   }
}

//+------------------------------------------------------------------+
//| ローソク足確定時の処理
//+------------------------------------------------------------------+
bool TaskPeriod() {
    static    datetime s_lasttime;                      // 最後に記録した時間軸時間
                                                        // staticはこの関数が終了してもデータは保持される

    datetime temptime    = iTime( Symbol(), Period() ,0 );  // 現在の時間軸の時間取得

    if ( temptime == s_lasttime ) {                     // 時間に変化が無い場合
        return false;                                         // 処理終了
    }
    s_lasttime = temptime;                              // 最後に記録した時間軸時間を保存

    // ----- 処理はこれ以降に追加 -----------
    return true;                                        // 移動平均線のクロス判定
}

void drawVLine(color clr) {
    string obj_name = StringFormat("%s_%d", PREFIX_VLINE, Bars);
    int    chart_id = 0;

    ObjectCreate(chart_id,obj_name,                                 // オブジェクト作成
                 OBJ_VLINE,                                         // オブジェクトタイプ
                 0,                                                 // サブウインドウ番号
                 Time[0],                                           // 1番目の時間のアンカーポイント
                 0                                                  // 1番目の価格のアンカーポイント
                 );
    
    ObjectSetInteger(chart_id,obj_name,OBJPROP_COLOR,clr);          // ラインの色設定
    ObjectSetInteger(chart_id,obj_name,OBJPROP_STYLE,STYLE_SOLID);  // ラインのスタイル設定
    ObjectSetInteger(chart_id,obj_name,OBJPROP_WIDTH,1);            // ラインの幅設定
    ObjectSetInteger(chart_id,obj_name,OBJPROP_BACK,false);         // オブジェクトの背景表示設定
    ObjectSetInteger(chart_id,obj_name,OBJPROP_SELECTABLE,true);    // オブジェクトの選択可否設定
    ObjectSetInteger(chart_id,obj_name,OBJPROP_SELECTED,false);     // オブジェクトの選択状態
    ObjectSetInteger(chart_id,obj_name,OBJPROP_HIDDEN,true);        // オブジェクトリスト表示設定
    ObjectSetInteger(chart_id,obj_name,OBJPROP_ZORDER,0);           // オブジェクトのチャートクリックイベント優先順位
}